int leng=36, depth=36;

final int LOOPED=0, FIXED=1, FREE=2, MIXED=3;
boolean circular=true;
color colour;
color colours[]=new color[leng];
//int sinArray[]=new int[721];
Chain[] chainStack=new Chain[depth];
float tinc = TWO_PI/150;
float finc = TWO_PI/1000;
int drawStyle=3, mode=2, squareSize=10;
int dp=leng/2; // driver position

class Chain {
  int ends=LOOPED;    
  float amplitude=10, frequency=TWO_PI/180, phase=0, k=0.5;
  float v[]=new float [leng];
  float r[]=new float [leng];
  int xPos, yPos, oldxPos, oldyPos, c, i, t;

  void simulateStep(){
    // Forces between neighbours:
    for (i=1;i<leng-1;i++){
        v[i]+=k*(r[i-1]+r[i+1]-2*r[i]);
    }
    
    if (ends==LOOPED){
        v[0]+=k*(r[leng-1]+r[1]-2*r[0]);    
        v[leng-1]+=k*(r[leng-2]+r[0]-2*r[leng-1]);       
    }
    else if (ends==FIXED){
        v[0]+=k*(0-r[0]);    
        v[leng-1]+=k*(0-r[leng-1]);       
    }
    else if (ends==FREE){
        v[0]+=k*(r[1]-r[0]);    
        v[leng-1]+=k*(r[leng-2]-r[leng-1]);       
    }
    else if (ends==MIXED){
        v[0]+=k*(0-r[0]);    
        v[leng-1]+=k*(r[leng-2]-r[leng-1]);       
    }                

   for (i=0;i<leng;i++){
    	r[i]+=v[i];
    }
    r[dp]+=amplitude*sin(phase);
    phase+=frequency;
 }
 // end simulateStep
 
 void drawChain(int j){

  if (circular) {
    oldxPos=(int) (width/2+((height/4)+r[(leng-1)])*cos((leng-1)*TWO_PI/leng));
    oldyPos=(int)(height/2+((height/4)+r[(leng-1)])*sin((leng-1)*TWO_PI/leng));
  } 
  else {
    oldxPos=0;
    oldyPos=height/2;
  }
  if (drawStyle==2) {
    beginShape(POLYGON);
    if (!circular) {
      vertex(width, height);
      vertex(0,height);
    }
  }
  for (int i=0; i<leng; i++) {
    if (circular) {
      xPos=(int) (width/2+ ((height/4)+r[i])*cos(i*TWO_PI/leng));
      yPos=(int)(height/2+ ((height/4)+r[i])*sin(i*TWO_PI/leng));

    }
    else {
      xPos=(i*width)/leng;
      yPos=(int)(r[i]+height/2);
    }
    stroke (colours[i&255]);
    if (drawStyle==1) line(xPos, yPos, oldxPos, oldyPos);
    else if (drawStyle==0) point(xPos, yPos);
    else if (drawStyle==2) vertex(xPos, yPos);
    else if (drawStyle==3) {
      noStroke();
      fill (v[i],r[i]*2.0,r[i]*2.0);
      rect(i*squareSize, j*squareSize, squareSize, squareSize);
    }      
    
    oldxPos=xPos;
    oldyPos=yPos;
    }
    if (drawStyle==2) endShape();
    if (keyPressed){
      if (keyCode==UP) amplitude+=0.5;
      if (keyCode==RIGHT) frequency+=0.001;    
      if (keyCode==DOWN) amplitude-=0.5;
      if (keyCode==LEFT) frequency-=0.001;    
    }
 }

}


public void reset(){
  float t=PI/(leng*2);
  for (int j=0; j<depth; j++){  
    for (int i=0; i<leng; i++){
      chainStack[j].r[i]=0;
      chainStack[j].v[i]=0;          
    }
    chainStack[j].phase=0;//(float)j/10;
    chainStack[j].k=t;
    t*=pow(2.0,1.0/12.0);
    //t*=1.0595;
    }
}

void draw(){
  background(0);
  for (int j=0; j<depth; j++){
    chainStack[j].simulateStep();
    chainStack[j].drawChain(j);
  }
}

void dot (int xPos, int yPos) {
    point(xPos,yPos);
}

void setup() { 
  frameRate(60); 
  size(360,360);
  for (int j=0; j<depth; j++){
    chainStack[j]=new Chain();
  }
  setColours(mode);
  fill(0,leng,leng);
  reset();
  draw();
} 

void setColours(int mode){

  if (mode==0){
    colorMode(HSB,leng);
    for (int i=0; i<leng; i++){
      colours[i]=color(i,0,leng);
    }   
  }
  if (mode==1){
    colorMode(HSB,leng);
    for (int i=0; i<leng; i++){
      colours[i]=color(i,leng/2,leng);
    }   
  }
  if (mode==2){
    colorMode(HSB,leng);
    for (int i=0; i<leng; i++){
      colours[i]=color(i,leng,leng);
    }   
  }    
}

void keyPressed(){
    if (key=='0') drawStyle=(drawStyle+1)%4;
    if (key=='1') circular=!circular;
    //if (key=='2') ends=(ends+1)%3;
    if (key=='9') setColours((mode++)%3);   
    if (keyCode==' ') reset();    
}